求助：CMOS工艺流程Tsuprem程序

wu4004

如题，最近在做这方面的课题，有没有谁能帮帮我有关CMOS工艺流程的Tsuprem程序，或者是其中一部分也行的，或者Tsuprem的中文指导，谢谢！

sukisul

Tsuprem 4的使用手册里有个CMOS的例子的

darklord007

thanks for sharing

darklord007

thanks for sharing

nishuidegou

顶一下

shelbykuo

回复 5# nishuidegou

$ TMA TSUPREM-4 N-channel MOS application
$
$ 1. Identify the graphics driver
$ Default from DEFPDEV, TERM, or S4PCAP "default" entry used


$ 2. Beginning of the main loop
FOREACH    LD  ( 3 5 )

$ 3. Specify the mesh
MESH       GRID.FAC=1.5
MESH       DY.SURF=0.01  LY.SURF=0.04  LY.ACTIV=2.0

$ 4. Initialize  
INITIALIZE <100>  BORON=1E15  WIDTH=( 0.7 + ( LD / 10.0 ) ) DX=0.1

$ 5. Plot the initial mesh
SELECT     TITLE="Mesh for Delta=0.@{LD}"
PLOT.2D    SCALE  GRID  Y.MAX=3.0  C.GRID=2

$ 6. Initial oxide pad
DEPOSIT    OXIDE  THICKNESS=0.03

$ 7. P-well implant
IMPLANT    BORON  DOSE=1E12  ENERGY=35

$ 8. Use a point defect models that simulates OED
METHOD     PD.TRANS

$ 9. P-well drive
DIFFUSE    TEMP=1100  TIME=120  DRYO2  PRESS=0.02

$ 10. P-well doping profile
SELECT     Z=LOG10(BORON)  TITLE="Channel Doping (Delta=0.@{LD})"  
PLOT.1D    X.VALUE=0  RIGHT=3.0  BOTTOM=15  TOP=19    LINE.TYP=2  COLOR=2
LABEL      X=1.8  Y=18.5  LABEL="After p-well drive"  LINE.TYP=2  C.LINE=2

$ 11. Pad nitride
DEPOSIT    NITRIDE  THICKNESS=0.1

$ 12. Field implant and oxidation
IMPLANT    BORON  DOSE=5E13  ENERGY=80
DIFFUSE    TEMP=1000  TIME=360  WETO2

$ 13. Etch to remove the pad
ETCH       NITRIDE  ALL

$ 14. Vt adjust implant
IMPLANT    BORON  ENERGY=100  DOSE=1E12

$ 15. P-well doping profile
SELECT     Z=LOG10(BORON)
PLOT.1D    X.VALUE=0  ^AXES  ^CLEAR  COLOR=2
LABEL      X=1.8  Y=18.2  LABEL="After Vt implant"  LINE.TYP=1 C.LINE=2

$ 16. Print oxide and silicon thicknesses
SELECT     Z=1
PRINT.1D   X.VALUE=0.0  LAYERS

$ 17. Etch oxide
ETCH       OXIDE  TRAP  THICK=0.05

$ 18. Gate oxidation
DIFFUSE    TEMP=950  TIME=30  DRYO2

$ 19. Poly deposition
DEPOSIT    POLYSILICON  THICKNESS=0.3  DIVISIONS=4

$ 20. Poly and oxide etch between x = 0.0 and 0.5 microns
ETCH       POLY   LEFT  P1.X=0.5
ETCH       OXIDE  TRAP  THICK=0.04

$ 21. Deposit a thin layer of oxide
DEPOSIT    OXIDE  THICKNESS=0.02

$ 22. LDD implant
IMPLANT    PHOS  ENERGY=50  DOSE=5E13  IMPL.TAB=PHOSPHORUS

$ 23. LTO
DEPOSIT    OXIDE  THICK=0.2

$ 24. Establish a sidewall spacer
ETCH       OXIDE  TRAP  THICK=0.22

$ 25. Source/drain implant
IMPLANT    ARSENIC  ENERGY=100  DOSE=2E15

$ 26. Oxide etch
ETCH       OXIDE  LEFT  P1.X=0.5

$ 27. Use an oxidation model that understands polysilicon
METHOD     COMPRESS

$ 28. Source/drain reoxidation (including the polysilicon gate)
DIFFUSE    TEMP=900  TIME=30  DRYO2

$ 29. BPSG -- etch to open windows for aluminum contact
DEPOSIT    OXIDE  THICK=0.3
ETCH       OXIDE  LEFT  P1.X=0.3

$ 30. Metallization -- etch to create a source contact
DEPOSIT    ALUMINUM  THICK=0.5  SPACES=3
DEPOSIT    PHOTORESIST THICK=1.0
ETCH       PHOTORESIST RIGHT  P1.X=0.6
ETCH       ALUMINUM  TRAP  ANGLE=85  THICK=0.8
ETCH       PHOTORESIST ALL

$ 31. Reflect to form the complete structure; then save it
SAVEFILE   OUT.FILE=S4EX7AS@LD
STRUCTURE  REFLECT  RIGHT
SAVEFILE   OUT.FILE=S4EX7AP@LD  MEDICI

savefile out.f=s4ex7a@{LD}.tif tif

$ 32. End of loop
END