求助！！为啥hspice仿真会卡在这里呢

hebinyu

用的CNTFET库，有时候把其中的某些参数一改，或者反相器多了几个，仿真就会卡在图片这个位置，求助大家！！
这个是全部的网表

.TITLE SCAN
***************************************************
*For optimal accuracy, convergence, and runtime
***************************************************
*.options POST ACCT LIST NODE
.options AUTOSTOP
.options INGOLD=2     DCON=1
.options GSHUNT=1e-12 RMIN=1e-15
.options ABSTOL=1e-5  ABSVDC=1e-4
.options RELTOL=1e-2  RELVDC=1e-2
.options NUMDGT=4     PIVOT=13

.param   TEMP=27
***************************************************
***************************************************
*Include relevant model files
***************************************************
.lib 'D:\model\nano_model_39\CNFET.lib' CNFET
***************************************************
*Some CNFET parameters:

.param Ccsd=0      CoupleRatio=0
.param m_cnt=1     Efo=0.6   
.param Wg=0        Cb=20e-12
.param Lg=32e-9    Lgef=100e-9
.param Vfn=0       Vfp=0
.param m=19        n=0      
.param Hox=4e-9    Kox=4

.param Vdd=0.9V
***********************************************************************
* Define power supply
***********************************************************************

*Vdd     1     0     0.9

***********************************************************************
* Main Circuits
***********************************************************************
.subckt PTI IN OUT Vdd
* nFET
X2 OUT IN Gnd Gnd NCNFET Lch=Lg  Lgeff='Lgef' Lss=32e-9  Ldd=32e-9  
+ Kgate='Kox' Tox='Hox' Csub='Cb' Vfbn='Vfn' Dout=0  Sout=0  Pitch=20e-9  n1=10  n2=0  tubes=1
* pFET
X1 OUT IN Vdd Vdd PCNFET Lch=Lg  Lgeff='Lgef' Lss=32e-9  Ldd=32e-9  
+ Kgate='Kox' Tox='Hox' Csub='Cb' Vfbn='Vfn' Dout=0  Sout=0  Pitch=20e-9  n1=19  n2=0  tubes=1
.ends

.subckt NTI IN OUT Vdd
X2 OUT IN Gnd Gnd NCNFET Lch=Lg  Lgeff='Lgef' Lss=32e-9  Ldd=32e-9  
+ Kgate='Kox' Tox='Hox' Csub='Cb' Vfbn='Vfn' Dout=0  Sout=0  Pitch=20e-9  n1=19  n2=0  tubes=1
* pFET
X1 OUT IN Vdd Vdd PCNFET Lch=Lg  Lgeff='Lgef' Lss=32e-9  Ldd=32e-9  
+ Kgate='Kox' Tox='Hox' Csub='Cb' Vfbn='Vfn' Dout=0  Sout=0  Pitch=20e-9  n1=10  n2=0  tubes=1
.ends


.subckt STIB IN OUT Vdd
XTP1 Out Gnd Vdd Vdd PCNFET Lch=Lg  Lgeff='Lgef' Lss=32e-9  Ldd=32e-9
+ Kgate='Kox' Tox='Hox' Csub='Cb' Vfbp='Vfp' Dout=1  Sout=0  Pitch=20e-9  n1=8  n2=n  tubes=1
XTP2 DX Gnd Out Vdd PCNFET Lch=Lg  Lgeff='Lgef' Lss=32e-9  Ldd=32e-9
+ Kgate='Kox' Tox='Hox' Csub='Cb' Vfbp='Vfp' Dout=1  Sout=0  Pitch=20e-9  n1=16  n2=n  tubes=1
XTN1 Out IN Gnd Gnd NCNFET Lch=Lg  Lgeff='Lgef' Lss=32e-9  Ldd=32e-9
+ Kgate='Kox' Tox='Hox' Csub='Cb' Vfbn='Vfn' Dout=1  Sout=0  Pitch=20e-9  n1=10  n2=n  tubes=3
XTN2 DX IN Gnd Gnd NCNFET Lch=Lg  Lgeff='Lgef' Lss=32e-9  Ldd=32e-9
+ Kgate='Kox' Tox='Hox' Csub='Cb' Vfbn='Vfn' Dout=1  Sout=0  Pitch=20e-9  n1=19  n2=n  tubes=3
.ends

.subckt STIA IN OUT Vdd
XTP1 Out OUT Z1 Vdd PCNFET Lch=Lg  Lgeff='Lgef' Lss=32e-9  Ldd=32e-9
+ Kgate='Kox' Tox='Hox' Csub='Cb' Vfbp='Vfp' Dout=1  Sout=0  Pitch=20e-9  n1=13  n2=n  tubes=3
XTP2 Z1 IN Vdd Vdd PCNFET Lch=Lg  Lgeff='Lgef' Lss=32e-9  Ldd=32e-9
+ Kgate='Kox' Tox='Hox' Csub='Cb' Vfbp='Vfp' Dout=1  Sout=0  Pitch=20e-9  n1=19  n2=n  tubes=3
XTP3 Out IN Vdd Vdd PCNFET Lch=Lg  Lgeff='Lgef' Lss=32e-9  Ldd=32e-9
+ Kgate='Kox' Tox='Hox' Csub='Cb' Vfbp='Vfp' Dout=1  Sout=0  Pitch=20e-9  n1=10  n2=n  tubes=3

XTN1 Out IN Gnd Gnd NCNFET Lch=Lg  Lgeff='Lgef' Lss=32e-9  Ldd=32e-9
+ Kgate='Kox' Tox='Hox' Csub='Cb' Vfbn='Vfn' Dout=1  Sout=0  Pitch=20e-9  n1=10  n2=n  tubes=3
XTN2 Z2 IN Gnd Gnd NCNFET Lch=Lg  Lgeff='Lgef' Lss=32e-9  Ldd=32e-9
+ Kgate='Kox' Tox='Hox' Csub='Cb' Vfbn='Vfn' Dout=1  Sout=0  Pitch=20e-9  n1=19  n2=n  tubes=3
XTN3 OUT OUT Z2 Gnd NCNFET Lch=Lg  Lgeff='Lgef' Lss=32e-9  Ldd=32e-9
+ Kgate='Kox' Tox='Hox' Csub='Cb' Vfbn='Vfn' Dout=1  Sout=0  Pitch=20e-9  n1=13  n2=n  tubes=3
.ends
******pulse
.subckt NAND A B OUT Vdd

XP1 OUT A Vdd Vdd PCNFET Lch=Lg  Lgeff='Lgef' Lss=10e-9  Ldd=32e-9  
+ Kgate='Kox' Tox='Hox' Csub='Cb' Vfbn='Vfn' Dout=0  Sout=0  Pitch=20e-9  n1=19  n2=0  tubes=1
XP2 OUT B Vdd Vdd PCNFET Lch=Lg  Lgeff='Lgef' Lss=10e-9  Ldd=32e-9  
+ Kgate='Kox' Tox='Hox' Csub='Cb' Vfbn='Vfn' Dout=0  Sout=0  Pitch=20e-9  n1=19  n2=0  tubes=1

XN1 OUT A X Gnd NCNFET Lch=Lg  Lgeff='Lgef' Lss=10e-9  Ldd=32e-9  
+ Kgate='Kox' Tox='Hox' Csub='Cb' Vfbn='Vfn' Dout=0  Sout=0  Pitch=20e-9  n1=19  n2=0  tubes=1
XN2 X B Gnd Gnd NCNFET Lch=Lg  Lgeff='Lgef' Lss=10e-9  Ldd=32e-9  
+ Kgate='Kox' Tox='Hox' Csub='Cb' Vfbn='Vfn' Dout=0  Sout=0  Pitch=20e-9  n1=19  n2=0  tubes=1
.ends

*----------------------MAIN CIRCUITS----------
XP1 Dn Gnd VDD VDD PCNFET Lch=Lg  Lgeff='Lgef' Lss=10e-9  Ldd=32e-9  
+ Kgate='Kox' Tox='Hox' Csub='Cb' Vfbn='Vfn' Dout=0  Sout=0  Pitch=20e-9  n1=7  n2=0  tubes=1
XP2 X Gnd Dn VDD PCNFET Lch=Lg  Lgeff='Lgef' Lss=10e-9  Ldd=32e-9  
+ Kgate='Kox' Tox='Hox' Csub='Cb' Vfbn='Vfn' Dout=0  Sout=0  Pitch=20e-9  n1=13  n2=0  tubes=1
XP3 Q Dn VDD VDD PCNFET Lch=Lg  Lgeff='Lgef' Lss=10e-9  Ldd=32e-9  
+ Kgate='Kox' Tox='Hox' Csub='Cb' Vfbn='Vfn' Dout=0  Sout=0  Pitch=20e-9  n1=29  n2=0  tubes=1

XN1 Dn IN Y Gnd NCNFET Lch=Lg  Lgeff='Lgef' Lss=10e-9  Ldd=32e-9  
+ Kgate='Kox' Tox='Hox' Csub='Cb' Vfbn='Vfn' Dout=0  Sout=0  Pitch=20e-9  n1=11  n2=0  tubes=1
XN2 X IN Y Gnd NCNFET Lch=Lg  Lgeff='Lgef' Lss=10e-9  Ldd=32e-9  
+ Kgate='Kox' Tox='Hox' Csub='Cb' Vfbn='Vfn' Dout=0  Sout=0  Pitch=20e-9  n1=19  n2=0  tubes=1
XN3 Y PG1 Gnd Gnd NCNFET Lch=Lg  Lgeff='Lgef' Lss=10e-9  Ldd=32e-9  
+ Kgate='Kox' Tox='Hox' Csub='Cb' Vfbn='Vfn' Dout=0  Sout=0  Pitch=20e-9  n1=10  n2=0  tubes=1
XN4 Q PG1 Z Gnd NCNFET Lch=Lg  Lgeff='Lgef' Lss=10e-9  Ldd=32e-9  
+ Kgate='Kox' Tox='Hox' Csub='Cb' Vfbn='Vfn' Dout=0  Sout=0  Pitch=20e-9  n1=19  n2=0  tubes=1
XN5 Z IN_B Gnd Gnd NCNFET Lch=Lg  Lgeff='Lgef' Lss=10e-9  Ldd=32e-9  
+ Kgate='Kox' Tox='Hox' Csub='Cb' Vfbn='Vfn' Dout=0  Sout=0  Pitch=20e-9  n1=29  n2=0  tubes=1



XINB   IN  IN_B Vdd  STIA
XSTI1        Q Qfb Vdd STIA
XSTI2 Qfb Q Vdd STIA
******pulse
X1X1   CLK  CLK1 Vdd  PTI
XIX11  CLK1 CLK2 Vdd  NTI
XIX12  CLK2 CLK3 Vdd  PTI
*XIX2   CLK3 CLK4 Vdd  NTI
XPLUSE CLK CLK3 PG Vdd NAND
XPG PG PG1 Vdd PTI
*******************************
Vclk CLK 0  PULSE (0.9 0 2n 0.1p 0.1p 2n 4n)

VVoltageSource_1 Vdd Gnd  0.9
*VVoltageSource_2 IN Gnd  PULSE(0 0.9 0n 0.1n 0.1n 50n 100n)

*VVoltageSource_2 IN Gnd PWL(0ns 0,50ns 0,'50.001ns' 0.45,100ns 0.45,'100.001ns' 0.9)
VVoltageSource_2 IN Gnd PWL(0ns 0,10ns 0,'10.001ns' 0.45,20ns 0.45,'20.001ns' 0.9,30ns 0.9,'30.001ns' 0,
+40ns 0,'40.001ns' 0.45,50ns 0.45,'50.001ns' 0.9,60ns 0.9,'60.001ns' 0.45,70ns 0.45,'70.001ns' 0)

***********************************************************************
.tran 10p 100n

.MEASURE avg_pow AVG power FROM=1n TO=100n



.OPTION  POST MEASOUT
.end
***********************************************************************v

                               
登录/注册后可看大图