VCO hspice simulate??

kaizi0824

******A Novel VCO*****
.OPTIONS LIST NODE POST
M1 1 2 VDD VDD pch w=700n l=350n
M2 1 2 VDD VDD pch w=700n l=350n
M3 2 1 VDD VDD pch w=700n l=350n
M4 2 1 VDD VDD pch w=700n l=350n
Rbias1 Vbias Vout+ 1k
Rbias2 Vbias Vout- 1k
Rturn1 Vturne c+ 1k
Rturn2 Vturne c- 1k
Cb1 1 Vout+ 1n
Cb2 2 Vout- 1n
C1 c+ 0 1n
C2 c- 0 1n
L1 1 0 330p
L2 2 0 330p
MCv1 Vturne Vout+ Vturne Vturne pch w=700n l=350n
MCv2 Vturne Vout- Vturne Vturne pch w=700n l=350n
Vdd Vdd 0 1v
Vbias Vbias 0 1v
Vturne Vturne 0 0.5v

請問一下要下哪些指令才可以看到~震盪頻率~~turner range~~phase noise ~波形與數值

.MODEL pch pmos
.op
.END

拜託大大可以幫忙~謝謝

jjchun

u may use sweep to change the vtune

tomcheung

。mesure语句测量频率

ly_liangyan

HSPICE 是不能直接仿 V-F 特性的，你可以一个点一个点的测频率，然后拟合。

ritchie_ch

如果有hspice RF的feature, 才能仿真phase noise，同时也就能画出c-v曲线了

piao

measure

具体用法可见CIC的培训材料

mingwei

*Four stage ring oscillator
***** Initial Setup *************************************
.lib "mm0355v.l" tt
.global vdd gnd
***** Sub Circuit : One delaycell of VCO*****************  
.subckt delaycell vin2+ vin1+ vin1- vin2- vout+ vout- vctr vdd gnd
M1 vout+ vin1- gnd   gnd nch w=3u l=0.5u m=6
M2 vout- vin1+ gnd   gnd nch w=3u l=0.5u m=6
M3 vout+ vout- vdd   vdd pch w=3u l=0.5u
M4 vout- vout+ vdd   vdd pch w=3u l=0.5u
M5 vout+ vin2- vdd   vdd pch w=12u l=0.5u
M6 vout- vin2+ vdd   vdd pch w=12u l=0.5u
M7 vout+ vctr  vdd   vdd pch w=3u l=0.5u m=8
M8 vout- vctr  vdd   vdd pch w=3u l=0.5u m=8
.ic v(vin1+)=0v
.ends
****** Main Circuit : Four stage ring oscilator *********
xvco1 vout2p vout1n vout1p  vout2n v1a     v1b    vctr  vdd gnd delaycell
xvco2 vout1n v1a    v1b     vout1p v2a     v2b    vctr  vdd gnd delaycell
xvco3 v1a    v2a    v2b     v1b    vout2n  vout2p vctr  vdd gnd delaycell
xvco4 v2a    vout2n vout2p  v2b    vout1p  vout1n vctr  vdd gnd delaycell
C1 vout1p 0 0.3p
C2 vout1n 0 0.3p
C3 vout2p 0 0.3p
C4 vout2n 0 0.3p
****** Voltage Source **********************************
vdd vdd 0 dc 2v  
vctr vctr 0 dc 0v
****** Analysis and output****** ***********************
.op
.option post
.tran 0.01n  30n SWEEP vctr 0 2 0.1
.meas tran pvco1n trig v(vout1p) val=1.65v rise=10 targ v(vout1p) val=1.65v rise=11
.meas tran pvco1p trig v(vout1n) val=1.65v rise=10 targ v(vout1n) val=1.65v rise=11
.meas tran pvco2p trig v(vout2p) val=1.65v rise=10 targ v(vout2p) val=1.65v rise=11
.meas tran pvco2n trig v(vout2n) val=1.65v rise=10 targ v(vout2n) val=1.65v rise=11
.meas TRAN  frequency=PARAM('1/pvco1n')
*.alter
*.lib "mm0355v.l" ss
*.alter
*.lib "mm0355v.l" ff
*.alter
*.lib "mm0355v.l" sf
*.alter
*.lib "mm0355v.l" fs
*.tran 0.01n 40n
*.alter
*vctr vctr 0 dc 0.2v
*.alter
*vctr vctr 0 dc 0.4v
*.alter
*vctr vctr 0 dc 0.6v
*.alter
*vctr vctr 0 dc 0.8v
*.alter
*vctr vctr 0 dc 1v
*.alter
*vctr vctr 0 dc 1.2v
*.alter
*vctr vctr 0 dc 1.8v
.end

ly_liangyan

赞楼上一个

cirand

呵呵，一个网表胜过千言万语。
不过不知道现在的hspice能否仿真phase noise。在specteRF里仿真phase noise还是比较方便的

lalajie

現在的hspice 有hspicerf 可以跑phase noise
不過 假如要見到圖形的話要另外搭配一套cosmosscope
假如只見文字的話  他會產生一個.pn 的檔案

假如有寫錯的話請各位糾正 因為我也是第一次碰hspicerf