学习 Hspice 仿真 MOS LAN 一问

lesleo

** NMOS 0.25um Cascode LNA for GSM applications
** setup for s-parameter and noise parameter measurements

* Revision: 2.0, change to HB analysis and add measurements
* 2 tone HB analysis, 1 tone as input, 1 tone as interfere
* Port element as power source, sweep input power
*
.temp 27
.options post=2
.param   Vdd=2.3
.global  gnd
**
** Cascode LNA tuned for operation near 1 GHz
**
M1 _n4 _n3 _n5 _n5 CMOSN l=0.25u w=7.5u
+     as=15p ad=15p ps=19u pd=19u m=80
M2 _n6 _n1 _n4 _n4 CMOSN l=0.25u w=7.5u
+     as=15p ad=15p ps=19u pd=19u m=80
M3  rfo _n6 gnd gnd CMOSN l=0.25u w=7.5u
+     as=15p ad=15p ps=19u pd=19u m=40
r1 _vdd _n6 400
l1 _n5  gnd  l=0.9nH
l2 rfin _n3  l=13nH  
vvb _n1 gnd   dc=1.19 $ bias for common base device
vvdd _vdd gnd dc=Vdd
rfb  rfo _n6 120      $ feedback
**
** 50 Ohm input port (incl. bias), 255 Ohm output port.
**
$.param inputV=1m
$P1 rfin gnd  port=1 z0=50  dc = 0.595 hb 'inputV' 0 1 1 hb 'inputV' 0 1 2
.param inputP=1u
$P1 rfin gnd  port=1 z0=50  power=dBm dc = 2.48 hb 'inputP' 0 1 1 hb 'inputP' 0 1 2
P1 rfin gnd  port=1 z0=50  power=w dc = 1.77m hb 'inputP' 0 1 1 hb 'inputP' 0 1 2
P2 rfo _vdd  port=2 z0=255  $ port double
**
** Measure s-parameters and noise parameters
**
.hb tones=900meg 901meg nharms=6 6 sweep inputP 1u 3u 1u
*
.measure hb pin find pdbm(p1)[1,0] at=1u
.measure hb pout find pdbm(p2)[1,0] at=1u
.measure hb p3rd find pdbm(p2)[2,-1] at=1u
.measure hb IIP3=param('pin+(pout-p3rd)/2')
.measure hb OIP3=param('pout+(pout-p3rd)/2')
.print hb p(p1) pdbm(p1)
.print hb p(p2) pdbm(p2)
**
** Approximate parameters for TSMC 0.25 Process (MOSIS run T17B)
**
.MODEL CMOSN NMOS (                                LEVEL   = 49
+VERSION = 3.1            TNOM    = 27             TOX     = 5.8E-9
+XJ      = 1E-7           NCH     = 2.3549E17      VTH0    = 0.3819327
+K1      = 0.477867       K2      = 2.422759E-3    K3      = 1E-3
+K3B     = 2.1606637      W0      = 1E-7           NLX     = 1.57986E-7
+DVT0W   = 0              DVT1W   = 0              DVT2W   = 0
+DVT0    = 0.5334651      DVT1    = 0.7186877      DVT2    = -0.5
+U0      = 289.1720829    UA      = -1.300598E-9   UB      = 2.3082E-18
+UC      = 2.841618E-11   VSAT    = 1.482651E5     A0      = 1.6856991
+AGS     = 0.2874763      B0      = -1.833193E-8   B1      = -1E-7
+KETA    = -2.395348E-3   A1      = 0              A2      = 0.4177975
+RDSW    = 178.7751373    PRWG    = 0.3774172      PRWB    = -0.2
+WR      = 1              WINT    = 0              LINT    = 1.88839E-8
+XL      = 3E-8           XW      = -4E-8          DWG     = -1.2139E-8
+DWB     = 4.613042E-9    VOFF    = -0.0981658     NFACTOR = 1.2032376
+CIT     = 0              CDSC    = 2.4E-4         CDSCD   = 0
+CDSCB   = 0              ETA0    = 5.128492E-3    ETAB    = 6.18609E-4
+DSUB    = 0.0463218      PCLM    = 1.91946        PDIBLC1 = 1
+PDIBLC2 = 4.422611E-3    PDIBLCB = -0.1           DROUT   = 0.9817908
+PSCBE1  = 7.982649E10    PSCBE2  = 5.200359E-10   PVAG    = 9.31443E-3
+DELTA   = 0.01           RSH     = 3.7            MOBMOD  = 1
+PRT     = 0              UTE     = -1.5           KT1     = -0.11
+KT1L    = 0              KT2     = 0.022          UA1     = 4.31E-9
+UB1     = -7.61E-18      UC1     = -5.6E-11       AT      = 3.3E4
+WL      = 0              WLN     = 1              WW      = 0
+WWN     = 1              WWL     = 0              LL      = 0
+LLN     = 1              LW      = 0              LWN     = 1
+LWL     = 0              CAPMOD  = 2              XPART   = 0.5
+CGDO    = 5.62E-10       CGSO    = 5.62E-10       CGBO    = 1E-12
+CJ      = 1.641005E-3    PB      = 0.99           MJ      = 0.4453094
+CJSW    = 4.179682E-10   PBSW    = 0.99           MJSW    = 0.3413857
+CJSWG   = 3.29E-10       PBSWG   = 0.99           MJSWG   = 0.3413857
+CF      = 0              PVTH0   = -8.385037E-3   PRDSW   = -10
+PK2     = 2.650965E-3    WKETA   = 7.293869E-3    LKETA   = -6.070E-3)
*
.END




这么个例子，其中红色部分怎么理解．（是不是就在计算其　s　参数）．谢谢．　　
我是初学，抠破脑袋实在想不出是什么意思．望高手指点．
                                                              先行谢过．

lesleo

为什么没有人帮我呢 .