使用hspice进行开环仿真的问题

I_Am_Learning

今天看到罗广孝老师的cmos模拟电路设计与仿真   其中的对一个折叠共源共栅结构的开环仿真不太理解  网表如下
EX 11.1 CASCODE OP AMPS
.option post=2 numdgt=7 tnom=27
*VIN+  1  0  DC  0  pwl(0 -1 10n -1 20n 1 1u 1 1.01u -1 2u -1 2.01u -.1 3u -.1
3.01u .1
*+4u .1 4.01u -.1 5u -.1)  
VIN+  1  0  DC  0 ac 1
VNI-  2  0  dc 0  ac 0
VDD   3  0  DC  2.5  
VSS   0  4  DC  2.5  
CL  5   0   10PF
X1 1 2 3 4 5 OPAMP
.SUBCKT OPAMP 1 2 3 4 5
m1  8  1  6  4   NMOSl l=1u  w=35.9u
m2  9  2  6  4   NMOSl l=1u  w=35.9u
m3  6  7  4  4   NMOSl l=1u  w=91.6u
m4  8  11 3  3   PMOSl l=1u  w=80u
m5  9  11 3  3   PMOSl l=1u  w=80u
136
m6  13 12 8  8   PMOSl l=1u  w=80u
m7  5  12 9  9   PMOSl l=1u  w=80u
m8  14 13 15 4   NMOSl l=1u  w=36.36u
m9  5  13 16 4   NMOSl l=1u  w=36.36u
m10 15 14 4  4   NMOSl l=1u  w=36.36u
m11 16 14 4  4   NMOSl l=1u  w=36.36u
m12 12 7  4  4   NMOSl l=1u  w=114.53u
m13 11 12 10 10  PMOSl l=1u  w=80u
m14 10 11 3  3   PMOSl l=1u  w=80u
R1  11 12  2K
R2  13 14  2K
VBIAS 7  0   -1.6
.MODEL NMOSl NMOS VTO=0.70 KP=110U GAMMA=0.4 LAMBDA=0.04 PHI=0.7
+MJ=0.5 MJSW=0.38 CGBO=700P CGSO=220P CGDO=220P CJ=770U CJSW=380P  
+LD=0.016U TOX=14N
.MODEL PMOSl PMOS VTO=-0.7 KP=50U GAMMA=0.57 LAMBDA=0.05 PHI=0.8
+MJ=0.5 MJSW=0.35 CGBO=700P CGSO=220P CGDO=220P CJ=560U CJSW=350P  
+LD=0.014U TOX=14N
.ENDS

.op
*.tf v(3) vi1
.dc VIN+  -0.005 0.005 100u
.print dc v(5)
.ac dec 10 1 10MEG
.print ac vdb(5) vp(5)

*.dc VIN+  -2.5 2.5 0.1
*.iplot v(5)
*.tran 0.05u 5u 0 10n
*.print v(5) v(1)
.end

主要是vin+  和Vin-的初始dc 都是设置为0   我觉得这样相当于m1  m2的直流偏置为0  就不导通了啊   可是仿真结果是正常的  不理解啊
我换了个电路  把输入也一样设置  结果两个管子果断cutoff了
另外 对开环和闭环仿真的概念不很清楚   一开始我以为  区别就是子电路有没有补偿电容   最后发现所用的子电路是相同的  
新手  见笑了

frankaurora

因为VSS   0  4  DC  2.5