带隙基准工作电压的仿真

flying591 · 发表于 2008-9-2 08:46:26

怎么仿真带隙基准最低工作电压（VREF随VDD变化的曲线）
我用HSPICE
语句我是这样写的
V1 VDD O 1.8
.TEMP 40
.OP
.DC V1 0 1.8 0.001
.PRINT DC V(VREF)
.END
可仿真根本无法进行。出现
**warning** cannot find any usefulness of parameter sweeping:v1 just create it anyway
请教一下这是怎么回事啊?
该如何仿真呢？

fuyibin · 发表于 2008-9-2 09:13:21

第一行你写了个O，地应该写0
v1 vdd 0 dc 1.8
.temp 40
.op
.dc v1 0 1.8 0.1
.probe dc v(vref)
.end

再不行就把v1的电压设成parameter,扫描参数

*PTAT bandgap voltage reference two bjts q1:q2=1:8
.global vdd gnd
.option wl
.option post accurate 1
vsup vdd gnd dc 1.8
.param x=7k
.subckt op vinp vinn vout
***input
m1 d1 vinn s12 vdd p18 4u 0.4u
m2 d2 vinp s12 vdd p18 4u 0.4u
***load
m3 d1 d1 gnd gnd n18 12u 2u
m4 d2 d1 gnd gnd n18 12u 2u
***tail
m5 s12 vout vdd vdd p18 8u 0.4u
***2nd stage
m6 vout d2 gnd gnd n18 12u 1u
m7 vout vout vdd vdd p18 8u 0.4u
***
cc d2 vout 1p
.ends
x1 vinp vinn vout vout op
*vb vb gnd dc 1.25v
q1 gnd gnd vinn pnp18a25
q2 gnd gnd e2 pnp18a25 m=8
**Non-Silicide P+ Poly Resistance
*xr1 e2 vinp rpposab_ckt l=17u w=1u
*xr2 vref e3 rpposab_ckt l=132u w=1u
****
**Non-Silicide N+ Diffusion Resistance
*xr1 e2 vinp gnd rndifsab_ckt l=100u w=1u
*xr2 vref e3 gnd rndifsab_ckt l=785u w=1u
****
r1 e2 vinp x
r2 vref e3 '10*x'
m1 vinn vout vdd vdd p18 4u 0.4u
m2 vinp vout vdd vdd p18 4u 0.4u
m3 vref vout vdd vdd p18 4u 0.4u
q3 gnd gnd e3 pnp18a25
.lib '/fuyibin/model/Spice file/ms018_v1p3.lib' tt
.lib '/fuyibin/model/Spice file/ms018_v1p3.lib' bjt_tt
*.include '/fuyibin/model/Spice file/ms018_v1p3_res.ckt'
*.lib '/fuyibin/model/Spice file/ms018_v1p3.lib' res_ss
.dc temp -30 100 1
*sweep x 5k 12k 1k
.probe dc i(r1),i1(m2),i2(r2),i1(m3),v(e2)
.probe dc v(vinp,e2),v(vref,e3)
.probe dc r1=par('-1*v(vinp,e2)/i1(m2)'),r2=par('-1*v(vref,e3)/i1(m3)')
.op
.end

zhaoguolll · 发表于 2008-9-2 09:38:09

将V1设置为变量然后进行扫描。另外最低工作电压也不是这样就能得出。你还要看在你所得到的最低工作电压
情况下你电路的输出是否在你要求的范围内，你的电路中的管子是否处于你所设计的工作区域。如果不是，则
在各种corner下输出很容易不工作。

[ 本帖最后由 zhaoguolll 于 2008-9-2 09:39 编辑 ]