Perl内置特殊变量

射门靴 · 发表于 2012-9-4 16:29:25

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？注册

x

一、正则表达式特殊变量：
1、$n
　　:包含上次模式匹配的第n个子串
2、$& 　　:前一次成功模式匹配的字符串
3、$`　　
:前次匹配成功的子串之前的内容
4、$’ 　　:前次匹配成功的子串之后的内容
5、$+　　:前一次使用括号的模式匹配的字符串.

二、文件句柄特殊变量:
1、$|　　:如果设置为零,在每次调用函数write或print后，自动调用函数fflush,将所写内容写回文件
2、$%　　:当前输出页号
3、$=　　:当前每页长度
4、$-　　:当前页剩余的行数
5、$~　　:当前报表输出格式的名称.默认值是文件句柄名.
6、$^　　:当前报表输出表头格式的名称.默认值是带后缀”_TOP”的文件句柄名.

三、全局特殊变量:
1、$_和$ARG　　:默认输入和模式匹配内容.如果不指定接收输入的变量或执行模式匹配的字符串
2、$.和$NR　　:前一次读的文件句柄的当前行号
3、$/和$RS　　:输入记录分隔符,默认是新行字符.如用undef这个变量,将读到文件结尾
4、$,的$OFS　　:输出域分隔符.
5、$\和$ORS　　:输出记录分隔符
6、$:
　　 :断行字符,默认是”\n-”三个字符
7、$!　　:这个变量的数字值是errno的值,字符串值是对应的系统错误字符串
8、$@　　:命令eval的错误消息.如果为空,则表示上一次eval命令执行成功
9、$$　　:运行当前Perl脚本程序的进程号
10、$<　　:当前进程的实际用户号
11、$>　　:当前进程的有效用户号
12、$(　　:当前进程的实际组用户号
13、$)　　:当前进程的有效组用户号
14、$[　　:数组的数组第一个元素的下标,默认是0
15、$]　　erl的版本号
16、$ARGV　　:当使用”< >”读文件时,保存当前文件名

四、全局特殊数组变量:
1、@ARGV　　:保存命令行参数
2、@INC　　:保存查找Perl程序的目录
3、@_　　:在子程序内,这个数组变量包含传递给子程序的参数
4、%INC　　:散列表%INC包含所有用do或require语句包含的文件.关键字是文件名,值是这个文件的路径
5、%ENV　　:包含当前环境变量
五、全局特殊文件句柄
1、ARGV　　:遍历数组变量@ARGV中的所有文件名的特殊文件句柄
2、STDERR　　:标准错误输出句柄
3、STDIN　　:标准输入句柄
4、STDOUT　　:标准输出句柄
PERL内置变量
$-
　　当前页可打印的行数,属于Perl格式系统的一部分
$!
　　根据上下文内容返回错误号或者错误串
$” 　　列表分隔符
$# 　　打印数字时默认的数字输出格式
$$ 　　Perl解释器的进程ID
$% 　　当前输出通道的当前页号
$& 　　与上个格式匹配的字符串
$( 　　当前进程的组ID
$) 　　当前进程的有效组ID
$* 　　设置1表示处理多行格式.现在多以/s和/m修饰符取代之.
$, 　　当前输出字段分隔符
$. 　　上次阅读的文件的当前输入行号
$/ 　　当前输入记录分隔符,默认情况是新行
$: 　　字符设置,此后的字符串将被分开,以填充连续的字段.
$; 　　在仿真多维数组时使用的分隔符.
$? 　　返回上一个外部命令的状态
$@ 　　Perl解释器从eval语句返回的错误消息
$[ 　　数组中第一个元素的索引号
$ 　　当前输出记录的分隔符
$] 　　Perl解释器的子版本号
$^ 　　当前通道最上面的页面输出格式名字
$^A 　　打印前用于保存格式化数据的变量
$^D 　　调试标志的值
$^E 　　在非UNIX环境中的操作系统扩展错误信息
$^F 　　最大的文件捆述符数值
$^H 　　由编译器激活的语法检查状态
$^I 　　内置控制编辑器的值
$^L 　　发送到输出通道的走纸换页符
$^M 　　备用内存池的大小
$^O 　　操作系统名
$^P 　　指定当前调试值的内部变量
$^R 　　正则表达式块的上次求值结果
$^S 　　当前解释器状态
$^T 　　从新世纪开始算起,脚步本以秒计算的开始运行的时间
$^W 　　警告开关的当前值
$^X 　　Perl二进制可执行代码的名字
$_ 　　默认的输入/输出和格式匹配空间
$| 　　控制对当前选择的输出文件句柄的缓冲
$~ 　　当前报告格式的名字
$` 　　在上个格式匹配信息前的字符串
$’ 　　在上个格式匹配信息后的字符串
$+ 　　与上个正则表达式搜索格式匹配的最后一个括号
$< 　　当前执行解释器的用户的真实ID
$ 　　含有与上个匹配正则表达式对应括号结果
$= 　　当前页面可打印行的数目
$> 　　当前进程的有效用户ID
$0 　　包含正在执行的脚本的文件名
$ARGV 　　从默认的文件句柄中读取时的当前文件名
%ENV 　　环境变量列表
%INC 　　通过do或require包含的文件列表
%SIG 　　信号列表及其处理方式
@_ 　　传给子程序的参数列表
@ARGV 　　传给脚本的命令行参数列表
@INC 　　在导入模块时需要搜索的目录列表
$-[0]和$+[0] 　　代表当前匹配的正则表达式在被匹配的字符串中的起始和终止的位置
。

射门靴 · 发表于 2012-9-4 16:30:06

perl的特殊变量（看到的好文，轉貼一下）
让你的perl代码看起来更像perl代码，而不是像C或者BASIC代码，最好的办法就是去了解perl的内置变量。perl可以通过这些内置变量可以控制程序运行时的诸多方面。
本文中，我们一起领略一下众多内置变量在文件的输入输出控制上的出色表现。

行计数
我决定写这篇文章的一个原因就是，当我发现很多人都不知道“$.”内置变量的存在，这的确让我很吃惊。
我依然能看到很多人是这样写代码的：
代码

my $line_no = 0;
while (<FILE>) {
++$line_no;
unless (/some regex/) {
   warn "Error in line $line_no\n";
   next;
}
# process the record in some way
}

由于某些原因，很多人似乎完全忽略了“$.”的存在。而这个变量的作用就是跟踪当前记录号。因此上面的代码也可以这样来写：

while (<FILE>)
{
unless (/some regex/) {
   warn "Error in line $.\n";
   next;
}
# process the record in some way
}

译者注：通俗的说，这个内置变量就跟数据库中的记录指针非常相似，它的值就是你当前所读文件中的当前行号。

虽然使用此内置变量并不能让你少打多少字，但重要的是我们可以省去一些不必要的变量声明。
另一种利用此内置变量的方法就是与连续操作符(..)一起使用。当用在列表上下文中时，(..)是列表构建操作符。它将从给出的开始和结束元素之间创建所有的元素。例如：

my @numbers = (1 .. 1000);
@numbers将包含从1到1000之间所有的整数。

但是当你在一个表达式上下文中使用此操作符时（比如，作为一个声明的条件），它的作用就完全不一样了。第一个操作数（“..“左侧的表达式）将被求值，如果得出的值为假，此次操作将什么也不做并返回假值。如果得出的值为真，操作返回真值并继续依次返回下面的值直到第二个操作数（“..”操作符右面的表达式）返回真值。
我们举个例子解释一下。假设你有一个文件，你只想处理这个文件的某几个部分。这几个部分以"!! START !!"为开始，"!! END !!"为结束。
使用连续操作符你可以这样写这段代码：

while (<FILE>) {
if (/!! START !!/ .. /!! END !!/) {
   # process line
}
}

每一次循环，连续操作符就会检查当前行。如果当前行与“/!! START !!/”不匹配，则操作符返回假值并继续循环。当循环到第一个与/!! START !!/”相匹配的行时，连续操作符就会返回真值并执行if语句块中的代码。在while语句后面的循环中，连续操作符将再次检查“/!! END !!/”的匹配行，但是它直到找到匹配行后才会返回真值。这也就是说在"!! START !!" 和"!! END !!" 标记之间的所有行都将被处理。当找到/!! END !!/的匹配行后，连续操作符返回假并再次开始匹配第一个规则表达式。

这些与“$.”有什么关系呢？如果连续操作符的操作数有一个是常量的话，他们将被转化为整型数并于“$.”匹配。
因此输出一个文件的前10行内容我们可以这样写代码：

while (<FILE>) {
print if 1 .. 10;
}

关于“$.”最后要说明的一点是，一个程序中只有一个“$.”变量。如果你在从多个文件句柄中读数据，那么“$.”变量保存了最近读过的文件句柄中的当前记录号。如果你想要更复杂的解决此问题的方法那么你可以使用类似IO::FILE对象。这些对象都有一个input_line_number方法。

记录分隔符

“$/” 和 “$\”分别是输入输出记录分隔符。当你在读或者写数据时，他们主要控制用什么来定义一个“记录”。

让我更详细地给大家解释一下吧。当你第一次学习perl，第一次知道文件输入操作符的时候，也许你会被告知“<FILE>”就是从一个文件读
入一行数据，而读入的每一行都包括一个新行字符（“\n”）。其实你所知道的这些并不完全是真的，那只是一个很特殊的情况。实际上文件输入操作符（“<>”）读数据后会包含一个在“$/”中指定的文件输入分隔符。让我们来看一个例子：

假设你有一个文本文件，内容是些有趣的引文或者一些歌词或者一些别的什么东西。比如类似下面的内容：
代码

This is the definition of my life
%%
We are far too young and clever
%%
Stab a sorry heart
With your favorite finger

在这里有三段被一行“%%”分隔的引文。那么我们该如何从这个文件中一次读取一段引文呢。（译者注：这一段引文可是一行也可以是几行，比如例子中的第一段和第二段引文都是一行，而第三段引文是2行）
其中一个解决方法就是，一次从文件中读取一行，然后检查读入的行是否是“%%”。因此我们需要声明一个变量用来保存每次读入的数据，当遇到“%%”后重新组合先前读入的数据为一段完整的引文。哦，你还需要记得处理最后一段引文因为它最后没有“%%”。
这样的方法太过于复杂，一个简单的方法就是更改“$/”变量的内容。该变量的默认值是一个新行字符（“\n”），这也就是为什么“<>”
操作符在读取文件内容时是一次读一行。但是我们可以修改这一变量内容为我们喜欢的任意值。比如：

$/ = "%%\n";

while (<QUOTE>) {
chomp;
print;
}

现在我们每次调用“<>”，perl会从文件句柄中一次读取数据直到发现 “%%\n”为止。（不是一次读一行了）。
因此，当你用chomp函数来去掉读取数据的行分隔符时，就会删除“$/”变量中指定的分隔符了。在上例中经过chomp函数处理后的数据都会将 %%\n”删除。

更改perl的特殊变量

在我们继续之前，我需要提醒你的是，当你修改了这些特殊变量的值后，你会得到一个警告。问题就是这些变量中的多数是被强制在主包中
的。也就是说当你更改这些变量的值时，程序中用到这个值的地方（包括你包含的那些模块）都会给出警告。
比如如果你在写一个模块，且你在模块中更改了“$/”变量的值，那么当别人把你的模块应用到自己的程序中时就必须相应的修改其他模块
以适应程序的执行。所以修改特殊变量的值潜在地增加了查找bugs的难度。

因此我们应该尽可能的避免它。第一个避免的方法是在你用完了修改后的特殊变量的值后应该将该特殊变量重值回原始值。比如：
代码

$/ = "%%\n";

while (<QUOTE>) {
chomp;
print;
}

$/ = "\n";

而这个方法引发的另一个问题就是你不能确定在你重置特殊变量的值之前它的值就是系统默认值。
（译者注：比如如果你在“$/ = "%%\n";”之前就修改过“$/”变量的值(不是默认值“\n”），那么你最后重置回默认值肯定会引发错误的）
因此我们的代码应该像如下才对，如下：

$old_input_rec_sep = $/;
$/ = "%%\n";

while (<QUOTE>) {
chomp;
print;
}

$/ = $old_input_rec_sep;

上面的代码就避免了我们上述所说的bug，但是我们有另一个看起来更简练的方法。这个方法就是使用local来定义“$/”变量。如下：

{
local $/ = "%%\n";

while (<QUOTE>) {
   chomp;
   print;
}
}

我们将代码以一对大括号括起来。一般的，代码块往往与循环，条件或者是子程序有关联，但是在perl中是可以单独用大括号来说明一个代码块的。
而在这个代码块内用local定义的变量只在当前代码块中起作用。
综上所述，不更改perl的内置变量是一个很好的习惯，除非它被本地化在一个代码块中。

“$/”的其他值

下面给出一些你可以赋予“$/”变量的特殊值，这些值可以开启一些有趣的行为。第一个就是设置该变量为未定义。这将开启slurp模式，
开启该模式后我们可以一次性从一个文件中读取全部的文件内容。如下：
代码

my $file = do { local $/; <FILE> };

一个do语句块的返回值是语句块中最后一个表达式的值，如上面的do语句块的返回值就是“<>”操作符的返回值。而且由于“$/”变量被设置为 undef（未定义），所以返回的就是整个文件的内容。需要注意的是，我们不需要明确地指定“$/”变量为undef，因为所有的perl变量在定义的时候就被自动初始化为undef。

设置“$/”变量为undef和空值是有很大区别的：设置成空值意味着开启paragraph模式（即段落模式），在这种模式下，每个记录就是一段以一个或更多空行为结束的文本段落。也许你会认为这种效果和把“$/”变量被设置为“\n\n”的效果是一样的，但是他们还是有微妙的区别的。如果一定进行比较，那么应该把“$/”变量设置成为“\n\n+”才能和paragraph模式相同。（注意，这里只是比方说。实际上是不能将“$/”变量设置为规则表达式的）“$/”变量的最后一个特殊值就是可以将其设置为一个整数标量变量的引用或者是一个整数常量的引用。
在这种情况下，从文件句柄中每次读出的数据最多是“$/”变量指定的大小。（在这里我说“最多”是因为在文件的最后有可能剩余的数据大小小于“$/”变量指定的大小）。因此，如果你想每次读出2kb的数据那么你可以这样做：

{
local $/ = \2048;

while (<FILE>) {
   # $_ contains the next 2048 bytes from FILE
}
}

“$/” 和 “$.”

注意到当改变“$/” 变量的值时候也相应的改变了perl对于记录的定义因此也改变了“$.”变量的行为。“$.”变量实际上保存的不再是当前“行”号了，而是当前的记录号。因此在前述的那个引文的例子中，“$.”变量将按照你所要读出数据的文件中的每一段引文递增。

关于“$\”

在前面的开始我提到了“$/” 和“$\”变量作为输入和输出的记录分隔符。但是我们一直没有介绍“$\”变量。

说实话，“$\”并不像“$/”那么有用。它包含了每次调用print输出时在最后要增加的字符串。
它的默认值是空字符串，因此当你用print进行输出时，并没有任何东西跟在输出的数据后面。当然如果你非常希望能有个类似pascal的输出函数println，那么我们可以这样写：

sub println {
local $\ = "\n";
print @_;
}

这样，在你每次用print输出数据时都会在数据后面增加一个"\n"（即换行符）。

其它 Print 变量
接下来的两个需要讨论的变量是非常容易混淆，尽管它们做的是完全不同的两件事。为了举例说明，看下面代码：

my @arr = (1, 2, 3);
print @arr;
print "@arr";

现在，如果不仔细地看你是否知道上面两个print调用的区别吗？
答案是，第一个print调用会紧挨着输出数组的三个元素，其间没有任何分割符（输出为：123）。然而第二个print语句输出的元素确实以空格为分隔的（输出为：1 2 3）。为什么会有此区别呢？

理解这个问题的关键就是，在每种情况下实际传给print调用的是什么。在第一种情况下，传递给print的是一个数组。perl将展开传递过来的数组为一个列表，列表中的三个元素被视为单独的参数。而第二种情况下，在传递给print之前，数组被双引号所包含。
确切地说第二种情况也可以理解成如下的过程：

my $string = "@arr";
print $string;

因此，在第二种情况看来，传递给print函数的只是一个参数。事实上的结果就是对一个数组进行了双引号的包含，并不影响print函数是如何对待该字符串的。

因此摆在我们面前的就是两种情况。当print接收一组参数的时候，它将紧凑地将这些参数输出而在输出的参数之间没有空格。当一个数组被
双引号包含起来传递给print之前，数组的每个元素将以空格为分隔符展开为一个字符串。这两种情况是完全不相干的。不过从我们上面举的例子我们很容易看出人们是如何混淆这两种情况的。
当然，如果我们愿意，perl允许我们改变这种行为。“ $,”变量保存了分隔传递给print函数的参数所用到的字符串。正如上面介绍的，默认分割print参数的字符是空字符，当然这都是可以更改的：

my @arr = (1, 2, 3);
{
local $, = ',';

print @arr;
}

这段代码将输出1,2,3
相应地，当一个数组被双引号包含传递给print函数时，展开这个数组后用来分割元素的字符则保存在“$"”变量中。代码如下：
my @arr = (1, 2, 3);
{
local $" = '+';
print "@arr";
}
这段代码将输出 1+2+3

当然，在一个print语句的使用中“$"”变量并不是必须的。你可以用在任何被双引号包含的数组的地方。而且它也不仅仅是对数组才有效。
也可以用在哈希表上。

my %hash = (one => 1, two => 2, three => 3);
{
local $" = ' < ';

print "@hash{qw(one two three)}";
}

这将输出： 1 < 2 < 3