四字节除法程序

kjf888

MOV   SP,#70H
LOOP0:    MOV 0CH, #00h    ;除数低字节
          MOV 0DH, #00h
          MOV 0EH, #061h    ;除数高字节
          MOV 0FH, #0A8H
          MOV 08H, #01H
          MOV 09H, #0C9H
          MOV 0AH, #0C3H
          MOV 0BH, #080H
          ACALL   CHU40
          RET
;4字节除4字节商为4字节除法子程序CHU40
;被除数放在内部08H.09H.0AH.0BH 单元中,除数放在0C.0D.0E.0F单元中
;商数放在内部R4.R5.R6.R7单元中,余数放在10H.11H.12H.13H单元中.
;溢出时商为零。余数为被除数
;资源影响；R0--16H共24字节   PSW      运行总时间1.977毫秒


CHU40:    MOV R0, #20H
          MOV 10H, #00H
          MOV 11H, #00H
          MOV 12H, #00H
          MOV 13H, #00H
CHU47:    CLR C
          MOV A, 0BH
          RLC A
          MOV 0BH, A
          MOV A, 0AH ;被除和扩充位左移
          RLC A
          MOV 0AH, A
          MOV A, 09H
          RLC A
          MOV 09H, A
          MOV A, 08H
          RLC A
          MOV 08H, A
          MOV A, 13H
          RLC A
          MOV 13H, A
          MOV A, 12H
          RLC A
          MOV 12H, A
          MOV A, 11H
          RLC A
          MOV 11H, A
          MOV A, 10H
          RLC A
          MOV 10H, A
          MOV A, R7 ;商数左移
          RLC A
          MOV R7, A
          MOV A, R6
          RLC A
          MOV R6, A
          MOV A, R5
          RLC A
          MOV R5, A
          MOV A, R4
          RLC A
          MOV R4, A
          CLR C
          MOV A, 13H ;判断
          SUBB A, 0FH
          MOV R1, A
          MOV A, 12H ;判断
          SUBB A, 0EH
          MOV 14H, A
          MOV A, 11H
          SUBB A, 0DH
          MOV 15H, A
          MOV A, 10H ;判断
          SUBB A, 0CH
          MOV 16H, A
          JC  LOP490
          INC R7
          MOV 13H,R1 ;建立余数
          MOV 12H,14H
          MOV 11H,15H
          MOV 10H,16H
LOP490:   DJNZ R0, CHU47
          RET
更多精彩请看http://www.51dz.com/index.asp?i=kjf888