Samsung原版44B0X的Bootloader分析

xiyiapple

Bootloader相信对于ARM的学习来说是一个难点，但是却是一个无法回避的点，这几天我也一直在学习如何写一个正确的Bootloader，下面是一个Samsung原版44B0X的Bootloader。
个人的心得是，对于汇编（Bootloader是由汇编写的），你可以不会写，但是，你必须知道他的指令的含义，能看懂一个正确的Bootloader，知道每一步的含义，然后根据自己的硬件接口电路，来修改他的Bootloader，然后能用，能让自己程序烧进去，能跑就行了。
更多ARM文章，换衣访问个人博客http://blog.sina.com.cn/u/1217992037
注意，如果要用，不能硬搬下面的程序，每个系统的硬件不同，其BOOTLOADER也不相同！！！

1．中断向量表
    AREA    Init,CODE,READONLY
说明：

1.从代码看Init段就是要写入0x00地址的原始中断向量，因此把这个文件编译生成的44binit.O和Init填入ADS的Linker-Layout页对应项中(这样编译器会把该段代码编译到0X0地址。

2.这一部分按44B0数据手册中的中断的地址顺序列出了一个异常中断向量表(每个表项占4个字节)

3.例如 ADC 的中断向量为 0x000000c0 下面对应表中第49项位置;对应向量地址为 0x0+4*(49-1)= 0x000000c0




ENTRY                        ；入口                                 

;地址

    b ResetHandler     ;for debug                           ;0x0000 0000
    b HandlerUndef     ;handlerUndef                      ;0x0000 0004
    b HandlerSWI    ;SWI interrupt handler           ;0x0000 0008
    b HandlerPabort     ;handlerPAbort                     ;0x0000 000c
    b HandlerDabort     ;handlerDAbort                    ;0x0000 0010
    b .                     ;handlerReserved                  ;0x0000 0014
    b HandlerIRQ                                                   ;0x0000 0018
    b HandlerFIQ                                                   ;0x0000 001c


;以下参考44B0的手册:中断控制器一章.按地址顺序排列

VECTOR_BRANCH
    ldr pc,=HandlerEINT0    ;mGA    H/W interrupt vector table 0x0000 0020
    ldr pc,=HandlerEINT1    ;  
    ldr pc,=HandlerEINT2    ;
    ldr pc,=HandlerEINT3    ;
    ldr pc,=HandlerEINT4567 ;
    ldr pc,=HandlerTICK         ;mGA
    b .
    b .
    ldr pc,=HandlerZDMA0    ;mGB
    ldr pc,=HandlerZDMA1    ;
    ldr pc,=HandlerBDMA0    ;
    ldr pc,=HandlerBDMA1    ;
    ldr pc,=HandlerWDT         ;
    ldr pc,=HandlerUERR01   ;mGB
    b .
    b .
    ldr pc,=HandlerTIMER0   ;mGC
    ldr pc,=HandlerTIMER1   ;
    ldr pc,=HandlerTIMER2   ;
    ldr pc,=HandlerTIMER3   ;
    ldr pc,=HandlerTIMER4   ;
    ldr pc,=HandlerTIMER5   ;mGC
    b .
    b .
    ldr pc,=HandlerURXD0    ;mGD
    ldr pc,=HandlerURXD1    ;
    ldr pc,=HandlerIIC     ;
    ldr pc,=HandlerSIO           ;
    ldr pc,=HandlerUTXD0    ;
    ldr pc,=HandlerUTXD1    ;mGD
    b .
    b .
    ldr pc,=HandlerRTC           ;mGKA
    b .                     ;
    b .                     ;
    b .                     ;
    b .                     ;
    b .                     ;mGKA
    b .
    b .
    ldr pc,=HandlerADC          ;mGKB
    b .                     ;
    b .                     ;
    b .                     ;
    b .                     ;
    b .                     ;mGKB
    b .
    b .
;0xe0=EnterPWDN
    ldr pc,=EnterPWDN
通过这段代码,就在44B0的ROM中以0x00为起始地址的地方建立起了一张中断向量表，而且这个表的顺序完全符合44B0数据手册中对中断向量地址的定义要求。



2．一级与二级中断处理程序
在中断向量表中IRQ的地址处写入一条进入IRQ中断处理的指令，使IRQ发生中断时先到IRQ——SERIVE（一级中断处理程序）中对中断向量进行识别，再进入相应的在外部RAM中具体的IRQ中断程序。在此之间需要把中断向量表中的INT源中的中断与外部RAM中的与其对应的中断处理程序（二级中断处理程序）相对应，该操作是由一个宏来完成的，任何调用HandlerXXX HANDLER HandleXXX都将被下面的程序展开，该宏定义的代码用于将对应中断服务程序ISR的入口地址装载到PC中，可称之为“加载程序”

本初始化程序定义了一个34个字空间的数据区（在文件最后），用于存放相应中断服务程序的首地址。每个字空间都有一个标号，以HandleXXX命名。在向量中断模式下使用“加载程序”来执行中断服务程序。

向量中断和非向量中断模式的概念与区别

（一）向量中断模式是当CPU读取位于0x18处的IRQ中断指令的时候，系统自动读取对应于该中断源确定地址上的指令取代0x18处的指令，通过跳转指令系统就直接跳转到对应地址函数中，节省了中断处理时间提高了中断处理速度。例如 ADC 中断的向量地址为0xC0,则在0xC0处放如下代码：ldr PC,=HandlerADC 当ADC中断产生的时候系统会自动跳转到HandlerADC函数中处理中断。

（二）非向量中断模式处理方式是一种传统的中断处理方法，当系统产生中断的时候，系统将INTPND寄存器中对应标志位置位，然后跳转到位于0x18处的统一中断函数中；该函数通过读取INTPND寄存器中对应标志位来判断中断源，并根据优先级关系再跳到对应中断源的处理代码中处理中断。




1）设置缺省中断处理函数 。
    ;****************************************************
    ;*    Setup IRQ handler                       *
    ;****************************************************
    ldr       r0,=HandleIRQ              ;This routine is needed
    ldr       r1,=IsrIRQ                   ;if there isn't 'subs pc,lr,#4' at 0x18, 0x1c
    str       r1,[r0]
2）IRQ中断处理函数
下面这段程序是用来处理非向量中断，具体判断I_ISPR中各位是否置1 置1表示目前此中断等待响应（每次只能有一位置1），从最高优先级中断位开始判断，检测到等待服务 ;中断就将pc置为中断服务函数首地址



IsrIRQ    ;using I_ISPR register.
    sub      sp,sp,#4       ;reserved for PC,为PC留下空位.
    stmfd   sp!,{r8-r9}           ;把r8,r9先入栈


    ldr       r9,=I_ISPR     ；读入I_ISPR中的值
    ldr       r9,[r9]
    mov     r8,#0x0
0
    movs    r9,r9,lsr #1    ；逻辑右移，得到中断源的编号
    bcs      %F1
    add      r8,r8,#4
    b         %B0


1
    ldr       r9,=HandleADC      
    add      r9,r9,r8          ；得到偏移地址
    ldr       r9,[r9]            ；得到相应的IRQ程序地址
    str       r9,[sp,#8]              ；把IRQ程序的地址当成PC值入栈
    ldmfd   sp!,{r8-r9,pc} ；对PC赋值,转到新的中断程序处。
3）定义一个加载宏。
    MACRO
$HandlerLabel HANDLER $HandleLabel


$HandlerLabel
;由于ADS仅支持FD（满递减）型堆栈
    sub      sp,sp,#4             ;decrement sp(to store jump address)
    stmfd   sp!,{r0}              USH the work register to stack(lr does't push because it return to original address)
;将要使用的R0寄存器压栈保护。
    ldr       r0,=$HandleLabel   ;load the address of HandleXXX to r0
    ldr       r0,[r0]                ;load the contents(service routine start address) of HandleXXX
    str       r0,[sp,#4]                  ;store the contents(ISR) of HandleXXX to stack
;将对应的中断函数首地址入栈保护
    ldmfd   sp!,{r0,pc}          OP the work register and pc(jump to ISR)
;将中断函数的首地址出栈，放入PC中，系统将跳转到对应中断处理函数   
4）宏调用
通过了这部分的程序，我们可以发现，在每一个IRQ中断的入口地址处，都写入了一个与其相关联的IRQ服务程序的地址。

下面是具体的中断处理函数跳转的宏，通过上面的$HandlerLabel的宏定义展开后跳转到对应的中断处理函数（ISR）处理中断（对于向量中断）



HandlerFIQ            HANDLER HandleFIQ
HandlerIRQ           HANDLER HandleIRQ
HandlerUndef  HANDLER HandleUndef
HandlerSWI           HANDLER HandleSWI
HandlerDabort HANDLER HandleDabort
HandlerPabort HANDLER HandlePabort


HandlerADC          HANDLER HandleADC
HandlerRTC           HANDLER HandleRTC
HandlerUTXD1      HANDLER HandleUTXD1
HandlerUTXD0      HANDLER HandleUTXD0
HandlerSIO            HANDLER HandleSIO
HandlerIIC             HANDLER HandleIIC
HandlerURXD1      HANDLER HandleURXD1
HandlerURXD0      HANDLER HandleURXD0
HandlerTIMER5     HANDLER HandleTIMER5
HandlerTIMER4     HANDLER HandleTIMER4
HandlerTIMER3     HANDLER HandleTIMER3
HandlerTIMER2     HANDLER HandleTIMER2
HandlerTIMER1     HANDLER HandleTIMER1
HandlerTIMER0     HANDLER HandleTIMER0
HandlerUERR01     HANDLER HandleUERR01
HandlerWDT         HANDLER HandleWDT
HandlerBDMA1      HANDLER HandleBDMA1
HandlerBDMA0      HANDLER HandleBDMA0
HandlerZDMA1      HANDLER HandleZDMA1
HandlerZDMA0      HANDLER HandleZDMA0
HandlerTICK         HANDLER HandleTICK
HandlerEINT4567  HANDLER HandleEINT4567
HandlerEINT3 HANDLER HandleEINT3
HandlerEINT2 HANDLER HandleEINT2
HandlerEINT1 HANDLER HandleEINT1
HandlerEINT0 HANDLER HandleEINT0
结合1中的代码：

VECTOR_BRANCH

    ldr pc,=HandlerEINT0    ;mGA    H/W interrupt vector table 0x0000 0020

。。。。。。

我们很容易发现，这里通过向PC赋值的方法，直接跳转到处理HandlerEINT0的程序处



3．设置存储相关寄存器的程序
主要设置SDRAM,flash ROM 存储器连接和工作时序的程序,以及片选定义的程序;SMRDATA map在下面的程序中定义 ;SMRDATA中涉及的值请参考memcfg.s程序 ;具体寄存器各位含义请参考S3C44B0X Specification



   
;****************************************************
    ;*    Set memory control registers               *     
    ;****************************************************
    ldr       r0,=SMRDATA
    ldmia   r0,{r1-r13}
    ldr       r0,=0x01c80000  ;BWSCON Address
    stmia   r0,{r1-r13}


这是上面提到的对存储寄存器初始化的数据映射表（DATA Map）


SMRDATA DATA
       DCD 0x11110090   ;Bank0=OM[1:0], Bank1~Bank7=16bit, bank2=8bit;
      DCD ((B0_Tacs<<13)+(B0_Tcos<<11)+(B0_Tacc<<8)+(B0_Tcoh<<6)+(B0_Tah<<4)+(B0_Tacp<<2)+(B0_PMC))    ;GCS0
       DCD ((B1_Tacs<<13)+(B1_Tcos<<11)+(B1_Tacc<<8)+(B1_Tcoh<<6)+(B1_Tah<<4)+(B1_Tacp<<2)+(B1_PMC))    ;GCS1
       DCD ((B2_Tacs<<13)+(B2_Tcos<<11)+(B2_Tacc<<8)+(B2_Tcoh<<6)+(B2_Tah<<4)+(B2_Tacp<<2)+(B2_PMC))    ;GCS2
       DCD ((B3_Tacs<<13)+(B3_Tcos<<11)+(B3_Tacc<<8)+(B3_Tcoh<<6)+(B3_Tah<<4)+(B3_Tacp<<2)+(B3_PMC))    ;GCS3
       DCD ((B4_Tacs<<13)+(B4_Tcos<<11)+(B4_Tacc<<8)+(B4_Tcoh<<6)+(B4_Tah<<4)+(B4_Tacp<<2)+(B4_PMC))    ;GCS4
       DCD ((B5_Tacs<<13)+(B5_Tcos<<11)+(B5_Tacc<<8)+(B5_Tcoh<<6)+(B5_Tah<<4)+(B5_Tacp<<2)+(B5_PMC))    ;GCS5
       DCD ((B6_MT<<15)+(B6_Trcd<<2)+(B6_SCAN))    ;GCS6
       DCD ((B7_MT<<15)+(B7_Trcd<<2)+(B7_SCAN))    ;GCS7
       DCD ((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Trc<<18)+(Tchr<<16)+REFCNT)       ;REFRESH RFEN=1, TREFMD=0, trp=3clk, trc=5clk, tchr=3clk,count=1019
       DCD 0x16                           ;SCLK power mode, BANKSIZE 32M/32M
       DCD 0x20                    ;MRSR6 CL=2clk
       DCD 0x20                    ;MRSR7


       ALIGN
4．初始化各模式下的堆栈指针
;****************************************************
;*    The function for initializing stack      *
;****************************************************
InitStacks
       ;Don't use DRAM,such as stmfd,ldmfd......
       ;SVCstack is initialized before
       ;Under toolkit ver 2.50, 'msr cpsr,r1' can be used instead of 'msr cpsr_cxsf,r1'


    mrs      r0,cpsr
    bic       r0,r0,#MODEMASK
    orr       r1,r0,#UNDEFMODE|NOINT
    msr      cpsr_cxsf,r1          ;UndefMode
    ldr       sp,=UndefStack
      
    orr       r1,r0,#ABORTMODE|NOINT
    msr      cpsr_cxsf,r1            ;AbortMode
    ldr       sp,=AbortStack


    orr       r1,r0,#IRQMODE|NOINT
    msr      cpsr_cxsf,r1            ;IRQMode
    ldr       sp,=IRQStack
      
    orr       r1,r0,#FIQMODE|NOINT
    msr      cpsr_cxsf,r1            ;FIQMode
    ldr       sp,=FIQStack


    bic       r0,r0,#MODEMASK|NOINT
    orr       r1,r0,#SVCMODE
    msr      cpsr_cxsf,r1            ;SVCMode
    ldr       sp,=SVCStack


       ;USER mode is not initialized.
    mov     pc,lr ;The LR register may be not valid for the mode changes.
5．对RW与ZI数据进行拷贝和初始化
应该从以下几个方面来理解这个问题：

1．在ADS中指定的参数ro_base和rw_base是指的是映像文件被加载后的内存地址。



2．RO中的数据是不需要再次拷贝到运行地址处的。

3．RO的代码的加载地址和运行地址是相同的。

4．说明：将数据段拷贝到RAM中,将ZI数据段清零,跳入C语言的main函数执行。到这里Bootloader初步引导结束。拷贝|Image$$RO$$Limit|起始的大小为（|Image$$ZI$$Base|－|Image$$RW$$Base|）的数据拷贝到|Image$$RW$$Base|对应的数据单元处。




    ;********************************************************
    ;*    Copy and paste RW data/zero initialized data             *
    ;********************************************************
    LDR           r0, =|Image$$RO$$Limit|      ; Get pointer to ROM data，
；获得ROM中的加载/运行时的RW地址
    LDR           r1, =|Image$$RW$$Base|      ; and RAM copy
                                        ；获得运行时的RW地址
    LDR           r3, =|Image$$ZI$$Base|        ；获得运行时的ZI地址
       ;Zero init base => top of initialised data
                     
    CMP           r0, r1          ; Check that they are different
                                                 ；比较指定的加载RW地址是否与运行时的RW地址相同。
BEQ           %F1                     ；如果相同不需要拷贝RW数据，因为它们的在加载和运行时的地址相同
0            
    CMP           r1, r3          ; Copy init data，因为对RW指定了不同的加载和运行地址，因此需要拷贝
    LDRCC   r2, [r0], #4       ;--> LDRCC r2, [r0] + ADD r0, r0, #4        
    STRCC   r2, [r1], #4         ;--> STRCC r2, [r1] + ADD r1, r1, #4
    BCC     %B0
1            
    LDR           r1, =|Image$$ZI$$Limit|       ；Top of zero init segmen
                                                                      ；初始化ZI数据为0
    MOV          r2, #0
2            
    CMP           r3, r1          ; Zero init
    STRCC   r2, [r3], #4
    BCC     %B2

kkyou

好文章

qqone

不错！！！

yrhui1981

好文章，顶一个