schReplaceLabels

YuSHL

sch中搜索替换labels
/**********************************************************************************************************
Function YschChangeLabel()
**********************************************************************************************************/
procedure(YschChangeLabel()
        let((labelText newLabelText obj)
                labelText = hiCreateStringField(
                        ?name 'labelText
                        ?prompt "Search labels:"
                        ?value ""
                )
                newLabelText = hiCreateStringField(
                        ?name 'newLabelText
                        ?prompt "Replace to:"
                        ?value ""
                )
                YschChangeLabelForm = hiCreateAppForm(
                        ?name 'YschChangeLabelForm
                        ?formTitle "Replace labels text form"
                        ?fields list(
                                list(labelText 0:0 400:30 100)
                                list(newLabelText 0:50 400:30 100)
                        )
                        ?buttonLayout 'OKCancelApply
                        ?callback "YschChangeLabelCB(hiGetCurrentForm())"
                        ?minSize 420:100
                )
                when(geGetSelSet() && css()->objType=="label"
                        YschChangeLabelForm->labelText->value = css()->theLabel
                )
                hiDisplayForm('YschChangeLabelForm)
        t
)
)

procedure(YschChangeLabelCB(form @optional cv(geGetEditCellView()) "rd")
        prog((labelText newLabelText)
                unless(form
                        warn("Can not get form database id - %A" form)
                        return()
                )
                when(form
                        labelText = form->labelText->value
                        newLabelText = form->newLabelText->value
                        YschChangeLabelMain(labelText newLabelText)
                )
        return(t)       
)
)

procedure(YschChangeLabelMain(labelText newLabelText @optional cv(geGetEditCellView()) "ttd")
        prog((objList)
                when(artBlankString(labelText) || artBlankString(newLabelText)
                        warn("The argument#1 and argument#2 can not be nil or blank string - %A, %A\n" labelText newLabelText)
                        return()
                )
                unless(cv&&cv->mode!="r"
                        warn("Can not get cellView id or current cellView is readable\n")
                        return()
                )
                if(geGetSelSet() then
                        objList = geGetSelSet()
                        else
                        objList = cv->shapes
                        warn("Not selected any objects in current cellView - %A, then search for all labels in current cellView\n" geGetSelSet())
                )
                objList = setof(x objList x->objType=="label")
                unless(objList
                        warn("Can not get any labels in current cellview - %A\n" objList)
                        return()
                )
                objList = setof(x objList x->theLabel==labelText)
                unless(objList
                        warn("There is not any labels - %A named - %A" objList labelText)
                        return()
                )
                foreach(obj objList
                        obj->theLabel = newLabelText
                )
        return(t)
)
)

acrofoxAgain

赞一个。你这个不局限与sch呀。

YuSHL

acrofoxAgain 发表于 2024-10-24 09:04
赞一个。你这个不局限与sch呀。

是的，本意是在sch中使用，layout可以使用原有的search功能

acrofoxAgain

原理图也可以用本来的Find/Replace功能吧？

YuSHL

acrofoxAgain 发表于 2024-10-24 09:58
原理图也可以用本来的Find/Replace功能吧？

Find好像不能找label，可能是我没用对吧

acrofoxAgain

YuSHL 发表于 2024-10-24 10:42
Find好像不能找label，可能是我没用对吧

Find里选Other，然后填theLabel

YuSHL

acrofoxAgain 发表于 2024-10-24 11:01
Find里选Other，然后填theLabel

好的，感谢，那后面再加一个如果label是Pin Name，加一个顺便改Pin textDisplay