HSPICE调用官网子电路出现仿真错误

blinker

使用hspice进行器件的仿真，下载官网spice模型后进行调用，显示官网模型中语法错误。
报错界面如下：

调用程序如下:
A SIMPLE TRANSIENT RUN
.OPTION POST =2 $选定显示格式
.OP $直流工作点
.TRAN 10N 100U $仿真步长10ns ，总时长100us
.PRINT TRAN V(1) V(4) $显示1，4节点电压波形
*ZETEX FMMT417 Spice Model v2.0 Last Revised 23/03/07
*下面就是官网给出的雪崩管模型文件，未改动
.SUBCKT FMMT417 16 15 14
*Pins______________C__B__E
Q_Q1          9  8  7 QMOD_1
R_R1          5  6  100  
R_R2          5  4  100
R_R3          12  3  100  
R_R4          3  1  500  
R_R5          10  2  2k  
R_R6          10  11  2
D_D1          10  5 DZ20
D_D2          4  2 DZ500
D_D3          10  3 DZ200
D_D4          1  2 DZ500
D_D5          7  9 DZ350
C_C1          10  2  20p  
S_S1         13  11  2  10  SMOD1 $显示这个语句语法出错了
S_S2          9  13  2  10  SMOD2
S_S3          8  10  2  10  SMOD3
V_H1          7  10  0
H1 6 10  V_H1 50
E1 12 10 11 10 10
L_L1          9  16  1nH  
L_L2          15  8  2nH  
L_L3          10  14  2nH  
.model QMOD_1 NPN IS =3E-14 NF =1 BF =110 IKF=0.4
+VAF=1900 ISE=1E-12 NE =1.6
+NR =1 BR =7 IKR=0.2 VAR=75 ISC=1e-10 NC =1.9
+RB =0.4 RE =0.1 RC =0.1
+CJC=10.9E-12 MJC=0.347 VJC=0.476 CJE=82.6E-12
+TF =1.3E-9 TR =2.3e-7
.model DZ20 D Is=1E-15  Bv=20 Ibv=100u
.model DZ200 D Is=1E-15  Bv=200 Ibv=100u
.model DZ350 D Is=1E-15 Rs=0.1 Bv=350 Ibv=100u
.model DZ500 D Is=1E-15 N=10 Bv=500 Ibv=100u
.model SMOD1 VSWITCH Roff=1e10 Ron=0.1 Voff=4.3 Von=4.6
.model SMOD2 VSWITCH Roff=1e3 Ron=1.0 Voff=4.5 Von=9
.model SMOD3 VSWITCH Roff=1e10 Ron=0.1 Voff=20 Von=25
.ENDS FMMT417
*
*$
*
Vin 1 0 PULSE (0 5 2NS 2NS 2NS 5US 10US)
R1 1 0 1K
X1 2 1 0 FMMT417
R2 3 2 1K
C1 4 2 680P
R3 4 0 51
V1 3 0 180

.END

求帮助

david_reg

"VSWITCH" 是Pspice里面的一种器件, 在hspice里面没有这种器件; 你可以根据Pspice里面的器件功能用hspice支持的器件(比如VCR)写一个类似VSWITCH功能的subckt再做仿真
https://www.seas.upenn.edu/~jan/ ... renceguideOrCAD.pdf
P218

blinker

是不是因为hspice中没有S模型？

xgreatful

都去看下S模型，要不要衬底也就是net  10，能不能对应上

blinker

好的学到了，不过现在用pspice跑这个模型了，还是谢谢您