OrCAD Pspice simulation error

kissshenzhu

HI ,I meet some problems when I simulated my analog circuit with philip's BF640 NPN transistor.
大家遇到象英飞凌的BJT器件，他提供了spice参数，例如：
***************************************************************
* Infineon Technologies AG
* GUMMEL-POON Transistor MODEL IN SPICE 2G6 SYNTAX
* BFP640 Model in SOT343
* Incuding 1/f Noise Model and Temperature Model
* June 2002
***************************************************************
*
* For DC-simulations, the parameter set is valid in the
* temperature range from  T = -25 癈 upto T = 125 癈.
* The AC-behaviour is correctly simulated only at T = 25 癈.
* In order to simulate S-Parameters at T = -25 癈 resp.
* T = 125 癈, the parameter ITF of the main transistor must
* be modified by the following equation:
*
* ITF(T) = ITF(To) * ( 1 - 6.5e-3 * (T-To) + 1.0e-5 * (T-To)^2 )
* To = 25 癈
*
* This means:
* -------------------------------
* ITF(-25 癈) = 1.35 * ITF(25 癈)
* ITF(125 癈) = 0.45 * ITF(25 癈)
*
* If in Parameter Set available set:
* TITF1 =  -6.5e-3
* TITF2 =   1.0e-5
**************************************************************
* BFP640
*
.OPTION TNOM = 25, GMIN = 1.0E-12
*
*         BFP640    C    B    E
.SUBCKT   BFP640    1    2    3
X1 22 11 33 2 1 3   SOT343_BFP640
X2 11 22 33         CHIP_BFP640
.ENDS BFP640
**************************************************************
* Chip parasitics BFP640
*
*         CHIP_BFP640    C    B    E
.SUBCKT   CHIP_BFP640    1    2    3
Q1     10    20    30    4    M_BFP640
CBEC   20    30               9.840E-14
CBCC   20    10               5.593E-14
LBC     2    20               1.200E-10
LCC     1    10               1.200E-10
LEC     3    30               2.000E-11
CES     3    33               1.800E-13
CBS     2    22               7.900E-14
CCS     1    11               7.500E-14
RBS     4    22               1.200E+03
RCS     4    11               1.200E+03
RES     4    33               3.000E+02
.ENDS CHIP_BFP640
**************************************************************
* Package Model SOT343 for BFP640
*
*       SOT343_BFP640 Bi  Ci  Ei  Bo  Co  Eo
.SUBCKT SOT343_BFP640  1   2   3  10  20  30
LBB     1    10               0.6962E-9
LCB     2    20               0.6824E-9
LEB     3    30               0.2306E-9
CCEO   20    30               131.2E-15
CBEO   30    10               102.5E-15
CCEI    2     3               112.6E-15
CBEI    3     1               180.4E-15
.ENDS SOT343_BFP640
**************************************************************
* BJT Model SOT343 for BFP640
*
.MODEL M_BFP640 NPN(
+ IS    = 2.200E-16   NF    = 1.025E+00   BF    = 4.500E+02   
+ NE    = 2.000E+00   ISE   = 2.100E-14   NR    = 1.000E+00   
+ BR    = 5.500E+01   NC    = 1.800E+00   ISC   = 4.000E-13   
+ VAF   = 1.000E+03   VAR   = 2.000E+00   IKF   = 1.500E-01   
+ IKR   = 3.800E-03   RB    = 3.129E+00   RBM   = 2.707E+00   
+ IRB   = 1.522E-03   RE    = 6.000E-01   RC    = 3.061E+00   
+ XTB   =-1.420E+00   EG    = 1.078E+00   XTI   = 3.000E+00   
+ TF    = 1.800E-12   VTF   = 1.500E+00   XTF   = 1.000E+01   
+ ITF   = 4.000E-01   CJE   = 2.276E-13   VJE   = 8.000E-01   
+ MJE   = 3.000E-01   CJC   = 6.743E-14   VJC   = 6.000E-01   
+ MJC   = 5.000E-01   XCJC  = 1.000E+00   CJS   = 9.335E-14   
+ VJS   = 6.000E-01   MJS   = 2.700E-01   FC    = 8.000E-01   
+ TR    = 2.000E-10   PTF   = 0.000E+00   AF    = 2.000E+00   
+ KF    = 7.291E-11   TITF1 =  -6.5e-3    TITF2 =   1.0e-5)

他里面有很多
.SUBCKT   CHIP_BFP640    1    2    3
.OPTION TNOM = 25, GMIN = 1.0E-12
.SUBCKT SOT343_BFP640  1   2   3  10  20  30
.MODEL M_BFP640 NPN
虽然我们做spice的时候只需要.MODEL M_BFP640 NPN就够了，但是我们有没有办法把这些参数做到一起去，生成一个spice model的器件库，这样仿真在ADS中会更加精准。

I meet the same problem with infineon BFP620 transistor.

[ 本帖最后由 kissshenzhu 于 2006-10-24 16:02 编辑 ]

kissshenzhu

已经解决，谢谢

flysmoke

怎么解决的阿，是参数问题？

shadow20

支持支持