串口通讯—RS-232-C详解（一）以及红外线遥控器解码程序

colderain

 红外线遥控是目前使用最广泛的一种通信和遥控手段。由于红外线遥控装置具有体积小、功耗低、功能强、成本低等特点，因而，继彩电、录像机之后，在录音机、音响设备、空调机以及玩具等其它小型电器装置上也纷纷采用红外线遥控。工业设备中，在高压、辐射、有毒气体、粉尘等环境下，采用红外线遥控不仅完全可靠而且能有效地隔离电气干扰。
1 红外遥控系统
通用红外遥控系统由发射和接收两大部分组成，应用编/解码专用集成电路芯片来进行控制操作，如图1所示。发射部分包括键盘矩阵、编码调制、LED红外发送器；接收部分包括光、电转换放大器、解调、解码电路。

2 遥控发射器及其编码
遥控发射器专用芯片很多，根据编码格式可以分成两大类，这里我们以运用比较广泛，解码比较容易的一类来加以说明，现以***NEC的uPD6121G组成发射电路为例说明编码原理。当发射器按键按下后，即有遥控码发出，所按的键不同遥控编码也不同。这种遥控码具有以下特征：
采用脉宽调制的串行码，以脉宽为0.565ms、间隔0.56ms、周期为1.125ms的组合表示二进制的“0”；以脉宽为0.565ms、间隔1.685ms、周期为2.25ms的组合表示二进制的“1”，其波形如图2所示。

上述“0”和“1”组成的32位二进制码经38kHz的载频进行二次调制以提高发射效率，达到降低电源功耗的目的。然后再通过红外发射二极管产生红外线向空间发射，如图3所示。

UPD6121G产生的遥控编码是连续的32位二进制码组，其中前16位为用户识别码，能区别不同的电器设备，防止不同机种遥控码互相干扰。该芯片的用户识别码固定为十六进制01H；后16位为8位操作码（功能码）及其反码。UPD6121G最多额128种不同组合的编码。
遥控器在按键按下后，周期性地发出同一种32位二进制码，周期约为108ms。一组码本身的持续时间随它包含的二进制“0”和“1”的个数不同而不同，大约在45～63ms之间，图4为发射波形图。
当一个键按下超过36ms，振荡器使芯片激活，将发射一组108ms的编码脉冲,这108ms发射代码由一个起始码（9ms）,一个结果码（4.5ms）,低8位地址码（9ms~18ms）,高8位地址码（9ms~18ms）,8位数据码（9ms~18ms）和这8位数据的反码（9ms~18ms）组成。如果键按下超过108ms仍未松开，接下来发射的代码（连发代码）将仅由起始码（9ms）和结束码（2.5ms）组成。
代码格式（以接收代码为准，接收代码与发射代码反向）
①位定义
        

②单发代码格式


③连发代码格式

注：代码宽度算法：
16位地址码的最短宽度：1.12×16=18ms 16位地址码的最长宽度：2.24ms×16=36ms
易知8位数据代码及其8位反代码的宽度和不变：（1.12ms+2.24ms）×8=27ms
∴32位代码的宽度为（18ms+27ms）~(36ms+27ms)

1． 解码的关键是如何识别“0”和“1”，从位的定义我们可以发现“0”、“1”均以0.56ms的低电平开始，不同的是高电平的宽度不同，“0”为0.56ms,“1”为1.68ms,所以必须根据高电平的宽度区别“0”和“1”。如果从0.56ms低电平过后，开始延时，0.56ms以后，若读到的电平为低，说明该位为“0”，反之则为“1”，为了可靠起见，延时必须比0.56ms长些，但又不能超过1.12ms,否则如果该位为“0”，读到的已是下一位的高电平，因此取（1.12ms+0.56ms）/2=0.84ms最为可靠，一般取0.84ms左右均可。
2． 根据码的格式，应该等待9ms的起始码和4.5ms的结果码完成后才能读码。
如果邮购我们开发的51单片机试验板和扩展元件的网友，可以获得如上图所示的红外遥控手柄，这种遥控器的编码格式符合上面的描述规律，而且价格低廉，有32个按键，按键外形比较统一，如果用于批量开发，可以把遥控器上贴膜换成你需要的字符，这为开发产品提供了便利。

接收器及解码
一体化红外线接收器是一种集红外线接收和放大于一体，不需要任何外接元件，就能完成从红外线接收到输出与TTL电平信号兼容的所有工作，而体积和普通的塑封三极管大小一样，它适合于各种红外线遥控和红外线数据传输。
ORG 0000H
START:MOV P0,#0FFH
MOV P1,#0FFH
MOV P2,#0FFH
MOV P3,#0FFH
JNB P3.2,$;等待遥控信号出现
MOV R6,#10
SB: ACALL YS1;调用882微秒延时子程序
JB P3.2,START;延时882微秒后判断P3.2脚是否出现高电平如果有就退出解码程序
DJNZ R6, SB;重复10次，目的是检测在8820微秒内如果出现高电平就退出解码程序
;以上完成对遥控信号的9000微秒的初始低电平信号的识别。
JNB P3.2, $ ;等待高电平避开9毫秒低电平引导脉冲
ACALL YS2 ;延时4.74毫秒避开4.5毫秒的结果码
MOV R1,#1AH ;设定1AH为起始RAM区
MOV R2,#4
PP: MOV R3,#8
JJJJ: JNB P3.2,$;等待地址码第一位的高电平信号
LCALL YS1;高电平开始后用882微秒的时间尺去判断信号此时的高低电平状态
MOV C,P3.2;将P3.2引脚此时的电平状态0或1存入C中
JNC UUU;如果为0就跳转到UUU
JB P3.2,$;如果为1就等待高电平信号结束
UUU: MOV A,@R1;将R1中地址的给A
RRC A;将C中的值0或1移入A中的最低位
MOV @R1,A;将A中的数暂时存放在R1中
DJNZ R3,JJJJ;接收地址码的高8位
INC R1;对R1中的值加1，换成下一个RAM
DJNZ R2,PP ;接收完16位地址码和8位数据码和8位数据反码，存放在1AH/1BH/1CH/1DH的RAM中
;以下对代码是否正确和定义进行识别
MOV A,1AH;比较高8位地址码
XRL A,#00000000B ;判断1AH的值是否等于00000000，相等的话A为0
JNZ EXIT;如果不相等说明解码失败退出解码程序
MOV A,1BH;比较低8位地址
XRL A,#11111111B ;再判断高8位地址是否正确
JNZ EXIT;如果不相等说明解码失败退出解码程序
MOV A,1CH;比较数据码和数据反码是否正确?
CPL A
XRL A,1DH ;将1CH的值取反后和1DH比较 不同则无效丢弃，核对数据是否准确
JNZ EXIT;如果不相等说明解码失败退出解码程序
CLR P2.7;解码成功发光二极管点亮指示!
AJMP BIJIAO
;判断在118毫秒内是否有连发码
AA:MOV R1,#25
XX:ACALL YS2
JNB P3.2,HH;跳转到判断连发代码是否正确的程序段
DJNZ R1,XX
EXIT: MOV P0,#0FFH;对所有端口清零
MOV P1,#0FFH
MOV P2,#0FFH
MOV P3,#0FFH
AJMP START
;连发码判断程序段-----------
HH:MOV R6,#4
S: ACALL YS1;调用882微秒延时子程序
JB P3.2,EXIT;延时882微秒后判断P3.2脚是否出现高电平如果有就退出解码程序
DJNZ R6, S;重复4次，目的是确认连发码的低电平信号波形
JNB P3.2, $ ;等待高电平
AJMP AA
BIJIAO:MOV A,1CH;按键数值判断执行
CJNE A,#00000101B,TT1
CPL P0.0
TT1: CJNE A,#00000100B,TT2
CPL P0.1
TT2: CJNE A,#00010000B,T3
CPL P0.2
T3: CJNE A,#01001101B,T5
CPL P0.3
T5: CJNE A,#01001110B,T6
CPL P0.4
T6: CJNE A,#01001100B,T7
CPL P0.5
T7: CJNE A,#00001001B,T8
CPL P0.6
T8: CJNE A,#00011101B,T9
CPL P0.7
T9: CJNE A,#00011111B,T10
CPL P2.6
T10: CJNE A,#00001101B,T11
CPL P2.5
T11: CJNE A,#00011001B,T12
CPL P2.4
T12: CJNE A,#00011011B,T13
CPL P2.3
T13: CJNE A,#00010001B,T14
CPL P2.2
T14: CJNE A,#00010101B,T15
CPL P2.1
T15: CJNE A,#00010111B,T16
CPL P2.0
T16: CJNE A,#00010010B,T17
CPL P1.0
T17: CJNE A,#00010110B,T18
CPL P1.1
T18: CJNE A,#01011110B,T19
CPL P1.2
T19: CJNE A,#01011101B,T20
CPL P1.3
T20: CJNE A,#01011100B,T21
CPL P1.4
T21: CJNE A,#01001111B,T22
CPL P1.5
T22: CJNE A,#00000001B,T23
CPL P1.6
T23: CJNE A,#00000011B,T24
CPL P1.7
T24: CJNE A,#00000000B,T25
CPL P3.0
T25: CJNE A,#00010100B,T26
CPL P3.1
T26: CJNE A,#00011110B,T27
CPL P3.3
T27: CJNE A,#00011010B,T28
CPL P3.4
T28: CJNE A,#00001111B,T29
CPL P3.5
T29: CJNE A,#00001010B,T30
CPL P3.6
T30: CJNE A,#00001110B,OK
CPL P3.7
OK:AJMP AA
YS1: MOV R4,#20 ;延时子程序1，精确延时882微秒
D1: MOV R5,#20
DJNZ R5,$
DJNZ R4,D1
RET
YS2: MOV R4,#10 ;延时子程序2，精确延时4740微秒
D2: MOV R5,#235
DJNZ R5,$
DJNZ R4,D2
RET
END
转贴:

dbjohn

真汗！

szguojian

顶啊!!!!!!!!!!!!!!111

zani

顶。。。。。。。。。。。。。。。。。。。。。。。。。。。。。。。

liuy

呵呵，看了不少遥控的东东。

liuy

就这个最贵了，呵呵，还是谢谢楼主。

colderain

我也是希望对大家有点用的
不用客气，呵呵

colderain

我也是希望对大家有点用的
不用客气，呵呵

overoo

好东西，收了

新型三极管

好东西就要顶，也随便赚个钱，呵呵