在设计一个PFC电源电路，高压管在Cadence中的建模不会

cmfjxga

哪一位仁兄可以提供Cadence中高压管子的建模的资料。
不管是管子的Spectre代码还是建模的步骤都好啊。
现在实验室也没有人做过，没有参考源啊。

哪一位好心人指点也行啊

xiaowanzi88

如果高压管是系统级的，去官方网站寻找相关型号的spice模型；
如果高压管是工艺厂商提供的，使用PDK就好了；
如果高压管没有spice，使用理想开关加寄生电阻，电容的形式建模；或者verilog-a建模带入仿真。

cmfjxga

回复 2# xiaowanzi88


    现在的想法就是采用veriloga模型，因为采用开关加上寄生电阻电容仿真出来的波形实在是太难看了。
所以想要一个能用的veriloga模型。

或者有谁能够把工艺厂商的模型贡献出来，那就真是感激不尽了。

还有一个问题就是，现在用pspice搭建的等效电路无法收敛，这是最让人蛋疼的了。

目前还在尽力寻找veriloga模型，ekv的模型貌似不太顶用啊，现在高压应用时要求800V耐压的

cmfjxga

回复 2# xiaowanzi88
成电是有这样的高压工艺的，那就要看成电同学愿不愿意奉献啊！

xiaowanzi88

回复 4# cmfjxga


    可惜我不是成电的，呵呵

cmfjxga

回复 5# xiaowanzi88

求教关于spectre高压管的模型，另外版主能否帮忙将帖子放在上面点，多谢啊


    其实浙大也是每年都有这方面的学生毕业，做的也是强电方向毕业，但是不知道他们的仿真期间里面高压管的建模到底是什么样子的。为啥我用pspice总是不会收敛，而且现在更加要命的是除了这个器件，别的器件都已经差不多了，总是不能使用，真是难受死了。


附上一段使用Faichild 800V 耐压器件FQD2N80的pspice代码，以及转码之后的.scs代码，但是不能使用。

pspice(来自Fairchild):
**************** Power Discrete MOSFET Electrical Circuit Model *****************
* Product Name: FQD2N80
* 800V N-Channel MOSFET and D-PAK
*--------------------------------------------------------------------------------
.SUBCKT FQD2N80 20 10 30
Rg 10 1 0.04
M1 2 1 3 3 DMOS L=1u W=1u
.MODEL DMOS NMOS(VTO=4.79136 KP=2.737
+ LEVEL=3)
Cgs 1 3 400p
Rd 20 4 3.7 TC=0.00875
Dds 3 4 DDS
.MODEL DDS D(BV=800  M=0.42   CJO=40p   VJ=0.012)
Dbody 3 20 DBODY
.MODEL DBODY D(IS=1.0E-12  N=1.00  RS=0.028  EG=1.12  TT=480n)
Ra 4 2 0.49 TC=0.00875
Rs 3 5 0.005
Ls 5 30 2.6n
M2 1 8 6 6 INTER
E2 8 6 4 1 2
.MODEL INTER NMOS (VTO=0 KP=10 LEVEL=1)
CGDMAX 7 4 560p
RCGD 7 4 1E7
DGD 6 4 DGD
RDGD 4 6 1E7
.MODEL DGD D(M=0.44 CJO=560p VJ=0.012)
M3 7 9 1 1 INTER
E3 9 1 4 1 -2
.ENDS
*--------------------------------------------------------------------------------
* Creation : Mar.-10-2004
* Fairchild Semiconductor


下面的代码是我经过spp转码之后的.scs代码，但是放在cadence spectre中不能使用，谁能教我步骤：
//  *************** Power Discrete MOSFET Electrical Circuit Model *****************
simulator lang=spectre insensitive=yes
//  Product Name: FQD2N80
//  800V N-Channel MOSFET and D-PAK
// --------------------------------------------------------------------------------
subckt fqd2n80 ( 20 10 30 )
rg ( 10 1 ) resistor r=0.04
m1 ( 2 1 3 3 ) dmos l=1u w=1u
model dmos mos3 type=n
+ vto=4.79136               kp=2.737                  
cgs ( 1 3 ) capacitor c=400p
rd ( 20 4 ) resistor r=3.7 tc1=0.00875
dds ( 3 4 ) dds
model dds diode
+ bv=800                    m=0.42                    cjo=40p
+ vj=0.012                  
dbody ( 3 20 ) dbody
model dbody diode
+ is=1.0e-12                n=1.00                    rs=0.028
+ eg=1.12                   tt=480n                  
ra ( 4 2 ) resistor r=0.49 tc1=0.00875
rs ( 3 5 ) resistor r=0.005
ls ( 5 30 ) inductor l=2.6n
m2 ( 1 8 6 6 ) inter
e2 ( 8 6 4 1 ) vcvs gain=2
model inter mos1 type=n
+ vto=0                     kp=10                     
cgdmax ( 7 4 ) capacitor c=560p
rcgd ( 7 4 ) resistor r=1e7
dgd ( 6 4 ) dgd
rdgd ( 4 6 ) resistor r=1e7
model dgd diode
+ m=0.44                    cjo=560p                  vj=0.012
m3 ( 7 9 1 1 ) inter
e3 ( 9 1 4 1 ) vcvs gain=-2
ends fqd2n80
// --------------------------------------------------------------------------------
//  Creation : Mar.-10-2004
//  Fairchild Semiconductor


可以看到转码之后，功率管的模型变为了subckt模型。
当时我的想法是在前面加代码：
library flyback_LED
section subckt

最末尾加上代码：
endsection subckt
endlibrary flyback_LED
但是在ADE仿真中按照通常的步骤加入这些东西貌似不管用。




有没有spectre模型方面的有经验前人可以指点一二，真是感激不尽了！！！

silverpuma

回复 6# cmfjxga


   建议用HSPICE跑电源系统，因为很多分离器件都是SPICE模型，而且可以直接从大公司的官网上面下载的。。。。。在Cadence的界面中调用HSPICED也可以跑仿真的